Powershot S95 & CHDK

[rdd]

Bonjour a tous,

Je viens de terminer mon script intervalometre/Autokap pour le S95 car il me manquait certaines fonctions dans les scripts existants.

Fonctions :
- Temporisation réglable avant la 1ere photo (pendant la montée)
- Bascule automatique en MF
- Possibilité de régler le niveau de zoom (initial)
- Réglage de intervalle en seconde (qui inclut la durée de la prise de vue)
- Extinction de l'écran pour économiser la batterie

C'est mon premier script merci de votre indulgence et de vos corrections si nécessaire

Code: Tout sélectionner

@title MyIntervalometer
@param b Delay 1st Shoot (Secs)
@default b 60
@param a Interval (Secs)
@default a 3
@param f Manual_Focus_Distance (mm)
@default f 11061
@param x Zoom Factor (x)
@default x 0
print "Starting"
press "shoot_full"
sleep 400
release "shoot_full"
get_prop 133 p
if p<>1 then
   c = 0
   while p<>1
      press "left"
      sleep 250
      release "left"
      sleep 250
       press "left"
      sleep 250
      release "left"
      press "set"
      sleep 250
      release "set"
      sleep 400
      get_prop 133 p
   wend
endif
if x>0 then
  for z=1 to x
      print "Zoom In: ", z;"x"
        press "zoom_in"
      sleep 250
      release "zoom_in"
      sleep 500
  next z
endif
print "SetFocus to ", f
set_focus f
print "Delay 1st Shoot"
for m=1 to b
  q=b-m
  print "Delay 1st shoot: ", q; "s"
  sleep 1000
next m
n=1
do
    print "shoot: ", n
    s = get_tick_count
   set_focus f
   sleep 400
   shoot
   sleep 400
        set_backlight 0
    sleep a*1000 - (get_tick_count - s)
    n = n + 1
until ( 0 )

Prochaines améliorations (en cours) :
- Zoom par palier (genre un coup de zoom toutes les xxx photos, réglable)
- Temporisation intermédiaire (genre tempo de xxx secondes toutes les nnn photos, réglable, pour éviter de prendre des photos pendant les déplacements au sol/repositionnement)

EDIT: Attention avec ce script car comme il éteint l'écran, à la récupération on n'y voit rien il faut éteindre l'appareil et le rallumer pour voir les photos, l'appuie sur la touche "déclenchement" arrête bien le script, mais ne rallume pas l'écran

[Deltakap]

Attention avec ce script car comme il éteint l'écran, à la récupération on n'y voit rien il faut éteindre l'appareil et le rallumer pour voir les photos

Bonjour rdd,

La fonction restore permet (en principe) de lancer des instructions à l'arrêt du script, comme par exemple la remise en route du LCD (si elle est supporté par le S95? sous chdk sinon sous sdm?.... à tester comme d'hab )
http://arch.ced.berkeley.edu/kap/discus ... ionID=2736

- Possibilité de régler le niveau de zoom (initial)

Tu as aussi la fonction set_zoom value, avec value de 0 à 7 ou 8 (suivant les apn's)... ça ne change pas grand chose mais c'est peut être plus jouli à lire
http://chdk.wikia.com/wiki/UBASIC/Scripts:_Zoom_Shoot


Edit: A quoi sert toute la partie avec get_prop 133 ? ça semble lié au focus ? mais encore ?
Re-edit.... ayé, j'ai trouvé (pour le Digic III & Digic IV).... 133 = Manual Focus Mode (0,1 = Off,On), mais je ne vois pas à quoi servent les press "left" ? un set_prop 133 1 n'est pas suffisant? (et est-il absolument nécessaire de faire ça si on force la valeur de focus? (ps: c'est une vraie question... j'en sais rien en fait)

Pour le focus, il y a aussi le set_prop 6 value, avec value = Focus Mode (0, 1, 3, 4, 5 = Normal, Macro, Infinity, Manual, Super Macro [SX10]). Set_prop 6 3 doit placer l'apn en focus infini sans avoir à déterminer une valeur pour set_focus (valeur un peu pifométrique)

[rdd]

Merci Gilbert ... décidément (cf arduino/mestro) tu es un vrai père pour moi

Je vais regarder les fonctions restore et set_zoom que je ne connaissais pas pour améliorer le truc

Edit: A quoi sert toute la partie avec get_prop 133 ? ça semble lié au focus ? mais encore ?
Re-edit.... ayé, j'ai trouvé (pour le Digic III & Digic IV).... 133 = Manual Focus Mode (0,1 = Off,On), mais je ne vois pas à quoi servent les press "left" ? un set_prop 133 1 n'est pas suffisant? (et est-il absolument nécessaire de faire ça si on force la valeur de focus? (ps: c'est une vraie question... j'en sais rien en fait)

Pour le focus, il y a aussi le set_prop 6 value, avec value = Focus Mode (0, 1, 3, 4, 5 = Normal, Macro, Infinity, Manual, Super Macro [SX10]). Set_prop 6 3 doit placer l'apn en focus infini sans avoir à déterminer une valeur pour set_focus (valeur un peu pifométrique)

J'ai fait plein d'essais pour en arriver là (avant de m'apercevoir que le plus simple est de régler le S95 en MF manuellement et d'enregistrer ça directement dans le mode 'C' ) :
- la prop 133 est en read only, on ne peut pas faire un set_prop
- la prop 6 n'est pas affectée par le changement de MF/AF (j'ai fait des Prop_Dump)
- click "mf" et press "mf" ne marchent pas sur le S95 (alors que ça marche très bien sur mon G10) c'est pour ça que je suis obligé de faire une série de press "left" (d'ailleurs le click "left" ne marche pas non plus ) jusqu'à être dans le mode MF (la touche de gauche sur le 'dial' à l'arrière du S95 sert au mode : MF / Normal / Macro) cela dit il y a peut être plus simple & plus propre mais je n'ai pas trouvé pour l'instant (et en plus : ça marche comme ça )

Olivier

[Deltakap]

tu es un vrai père pour moi

Snif, et encore un coup de vieux

- la prop 133 est en read only, on ne peut pas faire un set_prop

Bien vu .... Au temps pour moi

Je viens de regarder mon script. En fait, je fais l'équivalent de:

Code: Tout sélectionner

rem AiAF Mode off (0, 1, 2 = On, Off, FaceDetect)
set_prop 8 1
rem focus mode Infinity (0,1,3,4 = Normal, Macro, Infinity, Manual)
set_prop 6 3

Autofocus sur off et réglage de map à l'infini... il n'y a pas de MF/AF sur mon vieux (aussi ) 860, enfin je crois pas.

[rdd]

Dernière version.

Fonctions :
- Temporisation réglable avant la 1ere photo (pendant la montée)
- Bascule automatique en MF
- Possibilité de régler le niveau de zoom (initial)
- Réglage de intervalle en seconde (qui inclut la durée de la prise de vue)
- Extinction de l'écran pour économiser la batterie (réglable : ON/OFF dans le menu)
- Rallumage de l'écran à la fin (Merci Gilbert pour la fonction restore !)
- Zoom par palier (réglable dans le menu, quand le zoom maxi est atteint, le zoom est remis à zéro)

Code: Tout sélectionner

@title MyIntervalometer
@param b Delay 1st Shoot (Secs)
@default b 60
@param a Interval (Secs)
@default a 3
@param f Manual_Focus_Distance (mm)
@default f 11061
@param x Initial Zoom 1-10
@default x 0
@param c Zoom-speed 1-10
@default c 5
@param e Zoom every (n) photos
@default e 0
@param d Zoom step 1-10
@default d 1
@param l LCD (1=ON, 0=OFF)
@default l 1
if c<1 then c=1
if c>10 then c=10
c=c*10
if d<1 then d=1
if d>10 then d=10
print "Starting"
rem Une première photo... comme ça
press "shoot_full"
sleep 400
release "shoot_full"
rem On met le zoom à zéro
get_zoom r
set_zoom_speed c
if e>0 then
   print "Zooming-out..."
   set_zoom 0
endif
rem On passe en mode MF
get_prop 133 p
if p<>1 then
   c = 0
   while p<>1
      press "left"
      sleep 250
      release "left"
      sleep 250
       press "left"
      sleep 250
      release "left"
      press "set"
      sleep 250
      release "set"
      sleep 400
      get_prop 133 p
   wend
endif
if x>0 then
   print "Zooming-in ", x; "steps..."
   set_zoom_rel x
endif
print "SetFocus to ", f
set_focus f
sleep 800
print "Delay 1st Shoot"
for m=1 to b
  q=b-m
  print "Delay 1st shoot: ", q; "s"
  sleep 1000
next m
n=1
do
   if (n>=e) and (e>0) and (n%e = 0) then
      get_zoom g
      if (g + d)<10 then
         print "Zooming-in ", d; " steps..."
         set_zoom_rel d
         set_focus f
         sleep 800
      else
         print "Zooming-out..."
         set_zoom 0
         set_focus f
         sleep 800
      endif
   endif
    print "shoot: ", n
    s = get_tick_count
   set_focus f
   sleep 400
   shoot
   sleep 400
   if l=0 then set_backlight 0
    sleep a*1000 - (get_tick_count - s)
   n = n + 1
until ( 0 )

:restore
set_backlight 1
print "Resetting Zoom..."
set_zoom r
click "shoot_half"
print "Total shoots: ", n
end

[ormes]

Je vais finir par reluquer sérieusement les S95....

[plesage]

Je vais finir par reluquer sérieusement les S95....

Pascal, attends encore un peu, le S100 vient de sortir et la semaine dernière le S95 se vendait à USD 229 sur Amazon USA, il devrait encore baisser ...

[ormes]

Oui, mais je risque de passer à côté du S110....

[André]

Il est déjà sorti Pascal : dingue non ?



Avec un super capteur de 2.11 Mp

[yvo]

Ce script fonctionnerait il sur le s90 ?

Merci d'avance

Yvo

[rdd]

Je ne sais pas Yvo Si les deux S90/S95 sont en même version de 'DIGIC' et les mêmes 'propset' (je ne maitrise pas vraiment en fait) ça doit fonctionner. J'ai juste un doute sur le passage en mode MF (à cause de la propriété 133).

Le plus simple est peut être d'essayer ...

[yvo]

Bon ça marche pas ..... y'a quelqu'un qui pourrait faire ce genre de script pour S90 ?
Ce serait super cool.

Merci d'avance

Yvo

[Deltakap]

y'a quelqu'un qui pourrait faire ce genre de script pour S90 ?

Bonsoir Yvo,

Tu n'utilises pas l'ultra-intervalometer ? (le script que tu as copié sur dropbox : http://dl.dropbox.com/u/44507136/ult_intrvl.bas dans ce post viewtopic.php?f=3&t=3562&st=0&sk=t&sd=a&start=20)
Au fait, est-ce que ce script ultra-intervalometer fonctionne parfaitement sur le S90?
Et que voudrais-tu ajouter exactement à ce script?

Sinon, qu'est-ce qui coince avec le script de Rdd sur le S90?

Si les deux S90/S95 sont en même version de 'DIGIC' et les mêmes 'propset' .... ça doit fonctionner. J'ai juste un doute sur le passage en mode MF (à cause de la propriété 133).

@Olivier: D'après le wiki chdk, ils sont bien équipés tous les deux du processeur digic IV (http://chdk.wikia.com/wiki/S90 et http://chdk.wikia.com/wiki/S95), mais effectivement cette propriété 133 et surtout les "press left" ne plaisent peut-être pas au S90. Un truc curieux aussi (mais qui n'a peut-être aucun rapport voire aucune importance), c'est que les versions chdk supportées par ces deux appareils sont différentes !?

[rdd]

Arf ... désolé Yvo cela aurait pu fonctionner

Si un bas-normand équipé d'un S90 est d'accord pour me le prêter une petite semaine je veux bien me lancer

Ce qui ne me plait pas dans l'ultra intervalometer et qui m'a poussé à rédiger mon script, c'est la gestion par cycle. Le cycle comprend : le 'delay 1st shoot' puis xxx photos espacées de yyy secondes. Donc la temporisation "delay 1st shoot" est jouée à chaque cycle, c'est pas logique ! Du coup je me suis fait avoir, j'ai lancé la nacelle avec comme paramètre : delay 1st shoot 3 min, nbr de photos 1, intervalle 3 sec et 'endless' à '1' .... et ... j'ai volé comme ça 30 min ... et ... l'appareil a fait : 1 seule photo Il faut en effet mettre "2" photos sinon la boucle (endless) ne se fait pas C'est pas du tout logique comme approche, en tout cas, pas adapté. Notre besoin c'est : tempo avant la 1er photo, puis une boucle qui prend les photos jusqu'à ce qu'on arrête manuellement le script.

[Emmanuel]

Il faut faire gaffe car qu'il y a 2 (ou plus ?) versions du firmware du S90. Selon que ce soit le 1.01A et 1.01C (il me semble) il y a une version dédiée du chdk pour chacune de ces 2 versions de firmware.
Je l'avais oublié et c'est ce qui fait que je n'avais pas pu installer le chdk sur le S90 de Michel (Wirth) quand nous nous étions vus en octobre dernier.
Peut-être que dans le cas de RDD, c'est ce qui ne va pas.

[rdd]

Peut-être que dans le cas de RDD, c'est ce qui ne va pas.

Mon CHDK va très bien Emmanuel, je te remercie Le fonctionnement de l'ultra intervalometre que je décris est 'normal' (c'est expliqué sur sa page de Wiki). Je n'ai aucun problème avec les autres scripts (CamRemote, etc...) et j'arrive a peu près à faire ce que je souhaite (peut être en bricolant un peu )

[yvo]

Donc voila ce que j'aimerais :
en plus du script ultra intervallomètre qui me permet de faire x photos toutes les x secondes avec un délais pour la première photo, j'aimerais avoir le zoom par palier toutes les x photos et l'extinction de l'ecran.
Pour le moment pour le KAP, je n'utilise que le mode auto donc pas besoin de toucher à d'autres paramètres.

Lorsque je lance le sript de RDD sur mon S90, il commence par vouloir modifier l'ISO et fait une boucle sur ce paramètre.

Merci d'avance

Yvo

[rdd]

Yvo, c'est donc bien le passage en mode manuel qui est différent entre S95 et S90, je vais retirer ça du script et comme ça ça devrait passer.

[yvo]

Je relance un peu ce sujet, ...., si ce n'est pas trop abuser, ce serait possible de modifier le script pour que je puisse essayer .....

Yvo

[rdd]

oops je t'ai complètement oublié mon pauvre yvo s'cuse

En plus, je l'avais fait la modification car le passage en mode manuel me pose plein de soucis à moi aussi (sur le s95), alors j'ai maintenant deux scripts : un 'mf' et un 'af'. Voici la version 'af' :

Code: Tout sélectionner

@title MyIntervalometerAf
@param b Delay 1st Shoot (Secs)
@default b 60
@param a Interval (Secs)
@default a 3
@param x Initial Zoom 1-10
@default x 0
@param c Zoom-speed 1-10
@default c 5
@param e Zoom every (n) photos
@default e 0
@param d Zoom step 1-10
@default d 1
@param l LCD (1=ON, 0=OFF)
@default l 0
if c<1 then c=1
if c>10 then c=10
c=c*10
if d<1 then d=1
if d>10 then d=10
print "Starting"
rem Une première photo... comme ça
press "shoot_full"
sleep 400
release "shoot_full"
rem On met le zoom à zéro
get_zoom r
set_zoom_speed c
if e>0 then
   print "Zooming-out..."
   set_zoom 0
endif
if x>0 then
   print "Zooming-in ", x; "steps..."
   set_zoom_rel x
endif
print "Delay 1st Shoot"
for m=1 to b
  q=b-m
  print "Delay 1st shoot: ", q; "s"
  sleep 1000
next m
n=1
do
   if (n>=e) and (e>0) and (n%e = 0) then
      get_zoom g
      if (g + d)<10 then
         print "Zooming-in ", d; " steps..."
         set_zoom_rel d
         sleep 800
      else
         print "Zooming-out..."
         set_zoom 0
         sleep 800
      endif
   endif
    print "shoot: ", n
    s = get_tick_count
   shoot
   sleep 400
   if l=0 then set_backlight 0
    sleep a*1000 - (get_tick_count - s)
   n = n + 1
until ( 0 )

:restore
set_backlight 1
print "Resetting Zoom..."
set_zoom r
click "shoot_half"
print "Total shoots: ", n
end

[yvo]

Merci mais ça continue à planter......
le script se lance, zoom out et écran noir puis plus rien.....
Je crois que je vais continuer avec mon intervalometre classique.

Yvo

[SaintGermain]

Bonjour,

Je cherchais justement à faire du timelapse avec mon S95 mais je butais sur ce satané passage du focus en mode manuel.
Grâce à rdd j'ai enfin un script permettant cela. Merci !

Rdd, comment as-tu fait pour forcer le passage en mode manuel ?
J'ai bien pensé aux "click", mais ça ne marchait pas pour moi.
Probablement parce que je n'avais pas de "sleep" entre les "clicks".
Par contre à la main pour passer en mode manuel, normalement c'est "left", "right" et "set". Est-ce qu'il y a une raison pour faire plusieurs fois "left" et plusieurs fois "set" ?

Merci encore !

Code: Tout sélectionner

rem On passe en mode MF
get_prop 133 p
if p<>1 then
   c = 0
   while p<>1
      press "left"
      sleep 250
      release "left"
      sleep 250
       press "left"
      sleep 250
      release "left"
      press "set"
      sleep 250
      release "set"
      sleep 400
      get_prop 133 p
   wend
endif


[SaintGermain]

Ah oui et il semblerait que dans mon cas, l'écran ne soit pas complètement éteint.
Pendant une demi-seconde à chaque photo, l'écran se rallume et s'éteint.
Cela fait la même chose chez vous ?

Merci,

[kapitchi]

Récent possesseur d'un S95 j'ai pu tester le script, merci pour le partage.
C'est surtout pour le mode manuel et l'extinction du retroeclairage que j'utilise ce script (l'ultraintervallometre ne gerant ni l'un ni l'autre, la gestion des cycles par contre ne me pose pas probleme, habituellement je fixe un nombre de photos a 100-200 et je suis tranquille).

J'ai également le même problème du retroéclairage de l’écran qui se rallume/s'eteint (une demi-seconde) entre chaque prise de vue
Peut être la ligne suivante est à sortir de la boucle ? (il doit y avoir une bonne raison pour que le test soit fait a chaque itération)

Code: Tout sélectionner

if l=0 then set_backlight 0

[maka45]

Apparemment le lcd se rallume après chaque prise de vue,la demi-seconde correspondrait au sleep 400,ta ligne vérifie si tu as choisi l'option 'lcd off' et dans ce cas rééteint l'écran.
Tu peux toujours essayer de diminuer le 'sleep' mais...pas sur que ca en vaille la peine;(il ne détermine pas nécessairement le temps d'éveil de l'écran,mais permet à la ligne suivante de s'exécuter correctement).

Luc

[kapitchi]

Mmh pas mieux en virant le sleep apres le shoot, c'est même pire...
J'ai essayé l'astuce du sleep mappé sur la touche print, ca se met bien en veille mais de trop car l'appareil ne se reveille pas pour le shoot suivant...
Bon on va faire avec pour l'instant

[maka45]

Normalement ce Sleep ZZzz fonctionne aussi,mais:l'écran se réveille si tu secoues ou inclines l'apn.

[kapitchi]

Normalement ce Sleep ZZzz fonctionne aussi,mais:l'écran se réveille si tu secoues ou inclines l'apn.

Pas compatible avec le kap ça

[Wirth]

Bonjour ,
Hier j'ai reçu mon nouveau Canon S95 expedié depuis le Japon par Pierre ( plésage ) , et depuis hier j'essaie d'implanter le CHDK sur une carte SD de 2 GBits pour avoir la fonction intervallomètre . Mais malgré tous les liens fournis ( acid , stick , etc ..) et consultation de quelques retours d'expérience je ne suis toujours pas arrivé à quelque chose d'opérationnel . J'ai fais un medley de manipulations aléatoires qui font que j'ai un CHDK sur la carte SD, mais avec le célèbre ( et oh combien agaçant ) '' Default script " qui m'affiche : english language is missing . Comme je le faisais sur le S90 , je passe par le Firmware Update . Parmi pleins d'infos affichées à l'écran ( en anglais , ce qui est un comble !) il y a :SHUTTER=Run Script .Mais si j'appuie sur le déclencheur , le S95 ne s'ouvre même pas et donc l'intervallomètre ne fonctionne pas . J'ai essayé en verrouillant ou déverrouillant la carte SD . Et si j'allume le S95 avec le bouton ON , plus de CHDK bien sûr .Quelles que soient les manips que j'essaie , le S95 ne s'ouvre pas .Dernier affichage :
***Stardted ***
uBASIC :1 err
***TERMINATED ***
CCHDK3 . CFG
J'ai l'impression de me retrouver 2 ans en arrière , en pire .
Michel

[Deltakap]

Bonsoir Michel,

j'ai un CHDK sur la carte SD, mais avec le célèbre ( et oh combien agaçant ) '' Default script "

Ce message indique (entre autre) que tu n'as pas chargé le script d'intervalometre
Il faut d'abord que tu ailles le chercher et tu le mettes en route... la manip est là :
viewtopic.php?f=3&t=4778

[Wirth]

C'est un des retours d'exprérience que j'avais consulté , mais les affichages sur mon S95 sont différents . Par exemple j'ai: Script ( program your camera ) . Si je clique dessus j'arrive sur :Load script from file . J'ai programmé les mêmes données que Laurence , mais à aucun moment je n'ai en-dessous de " Save params " l'indication : intervalometer .
Michel

[Deltakap]

à aucun moment je n'ai en-dessous de " Save params " l'indication : intervalometer

Tu as trouvé le fichier "interval.bas" ? (dans "load script from file")
et tu l'as chargé en appuyant sur "funct. set" au milieu du stick ?

[Wirth]

Pas de fichier " interval.bas " nulle part !!!! Quand on clique sur Load script from file on arrive sur un écran avec une seule ligne :
../ <UpDir>b10.04'13 19:30 . Information dûe sûrement à une fausse manoeuvre de ma part à un moment ou un autre .
Il me semble pourtant que ce fichier est bien sur la carte SD , je vérifie tout de suite sur le lecteur .
Oui le fichier "interval.bas " est bien à sa place .
Michel

[Deltakap]

on arrive sur un écran avec une seule ligne :
../ <UpDir>b10.04'13 19:30 .

Et si tu fais un "funct. set" sur cette ligne, il t'affiche quoi ? (ça va faire un "updir" et remonter dans l'arborescence de la carte SD, où tu devrais trouver des fichiers... mais lesquels?)

Oui le fichier "interval.bas " est bien à sa place .

Dans le répertoire "CHDK\SCRIPTS" ?

[Wirth]

BINGO! Et une programmation CHDK réussie de plus pour Deltakap .
En fait , cette ligne UpDir .. était tellement différente de ce à quoi je m'attendais que j'étais simplement reparti en arrière .En cliquant dessus on affiche le dossier contenant entre autres interval.bas . Après ça va tout seul . L'intervallomètre fonctionne donc en passant par le Firmware Update . C'est déjà très bien , mais je voudrais arriver à le programmer comme sur mon Canon S90 : Après avoir allumé l'apn , j'appuie sur le petit bouton " S " , ensuite il me suffit d'appuyer sur le déclencheur pour démarrer l'intervallomètre , puis à nouveau sur le déclencheur pour l'arrêter . C'est le top , mais je sais que la manip est difficile , on a eu beaucoup de mal à le faire lors du week-end aérophoto à Bourges .
Merci Gilbert pour avoir débloquer une situation qui me paraissait sans issue .
Michel

[Deltakap]

mais je voudrais arriver à le programmer comme sur mon Canon S90 : Après avoir allumé l'apn , j'appuie sur le petit bouton " S " , ensuite il me suffit d'appuyer sur le déclencheur pour démarrer l'intervallomètre , puis à nouveau sur le déclencheur pour l'arrêter .

Normalement, il suffit de rendre la carte "bootable". Je ne sais pas si Stick le propose (je ne peux rien faire avec Stick sur mon vieux Canon ) mais sinon, il existe un petit utilitaire ultra simple à utiliser:
Tu télécharges EOScard ici : http://pel.hu/eoscard/ (bouton download dans le bandeau en haut), tu le lances et ça affiche quelque chose dans ce style là: (mais avec l'image chdk en gris et la case à cocher "BOOTDISK" pas encore cochée)



Tu vérifies que c'est bien la bonne carte qui s'affiche dans la ligne du haut (mais si tu n'as qu'une carte SD dans le/les lecteur(s) du PC, c'est forcement la bonne).
Tu as juste ensuite à cocher "BOOTDISK" (l'image chdk en dessous s'allume, mais c'est juste pour faire joli ) puis tu cliques sur le bouton "save" en haut à droite.... et c'est fini

Tu verrouilles la carte, tu la remets dans l'apn et ça doit démarrer sans avoir à faire le firmware update.

[Wirth]

Gilbert , t'es mon copain !
Parceque : ça marche !
Utilisateurs de Canon S90 ou S95 avec intervallomètre par CHDK , notez bien cette manip tellement simple .
MERCI Gilbert .
Michel

[titouyou]

Je savais que l'avais une bonne tête de vainqueur en matière de technique et ça se confirme. j'arrive avec la bouche en cœur fort de vos tutos sympas et mon S95 tout beau acheté de ce matin et paff dans Stick le premier truc qui peut merder c'est pour moi : no official build available. Pourtant j'ai pris plusieurs photos de base sans retouche rien nickel. donc si je regarde l'aide de Stick je ne peux pas faire grand chose.

[Emmanuel]

Noooon ???? C'est quoi le firmware de ton S95 ?

[titouyou]

en appliquant la technique Flickr il me dit 1.0