SX200 et camremote

[livo]

Bonjour, bonjour,
j'ai un problème de script avec le canon sx200 et le camremote. Le CR fonctionne correctement avec mon canon A590 en mode CHDK, mais le SX200 avec CHDK ou SDM ne comprend pas les impulsions envoyées par la CR. Si je shoot, l'apn prend la photo mais enchaîne sur le zoom, le focus, la video... puis finit par se bloquer. Je crois que j'ai un problème de script ou de firmware SDM avec le sx200.
J'ai déjà contacté Linnar qui m'a proposé plusieurs scripts mais sans effet.
Je ne sais pas si je suis très clair mais si quelqu'un pouvait m'aider ou me proposer sa configuration, j'ai peut-être oublié quelque chose.
Please.

[a906]

T'as investi dans le camremote ??

[livo]

c' top
radio in the pocket
autokap/manuel
zoom avec le chdk (avec un seul apn pour l'instant ).
j'ai même construit une petite nacelle picavet pour le joujou.
J'ai testé hier nacelle et radio (alim 3,5V), et à vue d'oeil j'avais 150m ou 200m de portée mais je ne suis pas allé plus loin.
Ya un bon potentiel.

[ormes]

En attendant des réponses (que je ne peux hélas pas te donner) à ta question, tu nous montrerais ta nacelle ? 3.5 ou 3.7, ou, formulé autrement, alim sur la batterie du gx ? Ca m'intéresse au cas où je sortirais le CR qui est toujours dans son sachet, depuis des mois...

[livo]

Mon 1er picavet :

Beaucoup d'aluminium (des restes), pignons d'une imprimante cassée, des vieux servos du temps ou je faisais du modélisme.
J'ai récupéré la batterie 3,6V du lumix de ma mère (elle l'a flingué en marchant dessus). Je ne sais pas si la batterie seule de mon apn pourrait alimenter apn, servos et récepteur.

[maka45]

En CHDK ca fonctionne avec le a590 mais pas avec le sx200?quelques idées en vrac :
vérifies que les 2 apn aient la meme configuration menu Canon et menu chdk;par exemple Focus Manual ou auto;Review time à zéro;Synchro off ou non....
Tu peux aussi tester l'usb remote sans le camremote(port usb du pc,insérer-désinsérer la prise)
Sinon,une différence entre le a590 et le sx200,qui nécessite sans doute une adaptation du script,c'est le nombre de zoom step,mais je suppose que Linnar le sait.

Luc

[ormes]

Sympa cette nacelle. Tenant du light, j'imaginerais bien un petit traitement amincissant, quand même. Et tu confirmes que tout marche en 3.6, ce qui permet d'envisager de tout faire fonctionner sur une batterie (APN, CR et servos). Même si elle dure moins longtemps, c'est surtout moins de barda à charger (dans tous les sens du terme). C'est un bon plan et je m'y mettrai peut-être après les ouacances. Merci pour la photo et l'info, et je te laisse aux affres du chdk.

[jdc]

Salut Livo,

En fait je pense que la tension appliqué sur l'USB (3,6V) n'est pas assez importante . Est-ce que ça déclenche quand tu branches le cable USB sur un PC? Voir http://chdk.wikia.com/wiki/CameraFeatures


(sinon très chouette réalisation )
@+
jdc

[livo]

Salut, merci pour votre aide.
Après 2 ou 3 mails avec Linnar et quelques essais au ubasic de mon côté, nous avons réussi , voici le script SDM qui va bien avec le canon sx200 (pour ceux qui auront le problème à l'avenir) :

Code: Tout sélectionner

@title CAMremote-SDM
rem by VP-Systems et Livo
rem 14-06-2011

m=0
z=0
set_zoom_speed 50
set_zoom 0
sync_off

rem goto "cr_fast"

rem CAMremote-1/2 (4-pin USB connector). Control Method: USB/CHDK
:cr_normal
print "CR: USB/CHDK"
while 1
  do
    a = get_usb_power
  until a>0
  print a
  if  a<6 then gosub "shoot"
  else if a>13 and a<22 then gosub "zin"
  else if a>21 and a<30 then gosub "zout"
  else if a>29 and a<36 then gosub "rec_video"
  else if a>35 and a<43 then gosub "avup"
  else if a>42 and a<49 then gosub "avdn"
  else if a>48 and a<55 then gosub "tvup"
  else if a>54 and a<61 then gosub "tvdn"
  else if a>60 and a<67 then gosub "stop_video"
  else if a>66 and a<73 then gosub "pwroff"
  else if a>72 and a<81 then gosub "pwroff"
 
  a=0
wend
end

rem CAMremote-2 (Mini USB connector).  Control Method: USB/CHDK+
:cr_fast
print "CR: USB/CHDK+"
while 1
  do
    a = get_usb_power
  until a>0
  if a<2 then gosub "shoot"
  else if a<4 then gosub "focus"
  else if a<6 then gosub "focusoff"
  else if a<8 then gosub "zin"
  else if a<10 then gosub "zout"
  else if a<12 then gosub "rec_video"
  else if a<14 then gosub "avup"
  else if a<16 then gosub "avdn"
  else if a<18 then gosub "tvup"
  else if a<20 then gosub "tvdn"
  else if a<22 then gosub "stop_video"
  else if a<42 then gosub "lensoff"
  else if a<52 then gosub "pwroff"

  a=0
wend
end

:shoot
  print "shoot:";a
  press "shoot_full"
  sleep 1500
  release "shoot_full"
  release "shoot_half"
  return

:rec_video
  if m=1 then return
  movie_mode
  sleep 2000
  print "rec_video:";a
  press "shoot_full"
  sleep 500
  release "shoot_full"
  m=1
  return

:stop_video
  if m=0 then return
  print "stop_video:";a
  press "shoot_full"
  sleep 500
  release "shoot_full"
  m=0
  sleep 2000
  record_mode
  return

:focus
  print "focus:";a
  press "shoot_half"
  return

:focusoff
  print "release:";a
  release "shoot_half"
  return

:zin
  if z<128 then z=z+15
  print "zoomin:";a
  set_zoom z
  sleep_for 500
  release "shoot_half"
  return

:zout
  if z<>0 then z=z-15
  print "zoomout:";a
  set_zoom z
  sleep_for 500
  release "shoot_half"
  return

:avup
  print "Av+:";a
  set_av_rel 0+1
  return

:avdn
  print "Av-:";a
  set_av_rel 0-1
  return

:tvup
  print "Tv+:";a
  set_tv_rel 0+1
  return

:tvdn
  print "Tv-:";a
  set_tv_rel 0-1
  return

:lensoff
  print "lensoff not supported"
  shut_down
  sleep 1000
  return

:pwroff
  print "poweroff"
  shut_down
  sleep 1000

return


Sinon j'ai vérifié la tension de mon accu(apn) elle est 4,3V juste après la charge et non 3,6V comme affiché sur l'étiquette. Le camremote fonctionne dessus environ 1h (peut-être moins) puis s'arrête alors que l'accu n'est pas vraiment déchargé mais la tension a baissé. Il faut que je continue les tests quand j'aurai un peu plus de temps.

[maka45]

Je vois qu'avec le script sdm tu peux stopper la vidéo à volonté?;est-ce également possible avec le script chdk?
Sinon,je suppose qu'il y avait un problème de détection(pas assez fine)de l'impulsion(pour une durée trop courte)?ou y avait-il un autre os...?

Luc

[livo]

Je vois qu'avec le script sdm tu peux stopper la vidéo à volonté?

Yes

est-ce également possible avec le script chdk?

Je ne sais pas, il n'y a pas de code pour la video dans le script chdk fourni par Linnar (cf site); sans doute que cela ne fonctionne pas ou alors Linnar a une préférence pour SDM.

Sinon,je suppose qu'il y avait un problème de détection(pas assez fine)de l'impulsion(pour une durée trop courte)?

Exact, d'où l'encadrement pour la valeur a de l'impulsion.

ou y avait-il un autre os...?

Le step zoom.
A pluch.